include (LibAddMacros)

find_package (PkgConfig)
pkg_check_modules (GLIB QUIET glib-2.0)

if (NOT GLIB_FOUND)
	exclude_binding (io_glib "glib-2.0 not found")
else ()

	# Build library
	add_binding (io_glib)

	set (BINDING_VARIANT glib)

	set (IO_VARIANT_SRC_FILES "${CMAKE_CURRENT_SOURCE_DIR}/io_glib.c")

	add_headers (ELEKTRA_HEADERS)
	set (SOURCES ${IO_VARIANT_SRC_FILES} ${ELEKTRA_HEADERS})

	set (IO_VARIANT_LIBRARY elektra-io-${BINDING_VARIANT})

	# create object library so that executables can use
	# $<TARGET_OBJECTS:OBJ_${IO_VARIANT_LIBRARY}>
	add_library (OBJ_${IO_VARIANT_LIBRARY} OBJECT ${SOURCES})
	target_include_directories (OBJ_${IO_VARIANT_LIBRARY} SYSTEM PUBLIC ${GLIB_INCLUDE_DIRS})

	add_lib (io-${BINDING_VARIANT} SOURCES ${SOURCES} LINK_ELEKTRA elektra-io LINK_LIBRARIES ${GLIB_LIBRARIES})

	if (BUILD_FULL OR BUILD_STATIC)
		add_includes ("elektra-full" ${GLIB_INCLUDE_DIRS})
	endif ()
	if (BUILD_SHARED)
		target_include_directories (${IO_VARIANT_LIBRARY} SYSTEM PUBLIC ${GLIB_INCLUDE_DIRS})
	endif ()

	configure_file ("${CMAKE_CURRENT_SOURCE_DIR}/${IO_VARIANT_LIBRARY}.pc.in"
			"${CMAKE_CURRENT_BINARY_DIR}/${IO_VARIANT_LIBRARY}.pc"
			@ONLY)

	install (FILES "${CMAKE_CURRENT_BINARY_DIR}/${IO_VARIANT_LIBRARY}.pc" DESTINATION lib${LIB_SUFFIX}/${TARGET_PKGCONFIG_FOLDER})

	# Build test
	set (testexename testio_${BINDING_VARIANT})

	set (TEST_SOURCES $<TARGET_OBJECTS:cframework>)
	add_headers (TEST_SOURCES)
	file (GLOB IO_TEST_SRC_FILES "${CMAKE_SOURCE_DIR}/src/bindings/io/test/test*.c")
	list (APPEND TEST_SOURCES ${IO_TEST_SRC_FILES})
	list (APPEND TEST_SOURCES "${CMAKE_CURRENT_SOURCE_DIR}/testio_${BINDING_VARIANT}.c")

	if (BUILD_FULL OR BUILD_STATIC) # add sources for elektra-io-glib for static and full builds
		list (APPEND TEST_SOURCES $<TARGET_OBJECTS:OBJ_${IO_VARIANT_LIBRARY}>)
	endif ()

	add_executable (${testexename} ${TEST_SOURCES})
	add_dependencies (${testexename} kdberrors_generated)

	target_include_directories (${testexename} PUBLIC "${CMAKE_SOURCE_DIR}/tests/cframework")
	target_include_directories (${testexename} PUBLIC SYSTEM ${GLIB_INCLUDE_DIRS})

	target_link_elektra (${testexename} elektra-kdb elektra-plugin elektra-io ${IO_VARIANT_LIBRARY} m)
	if (BUILD_FULL OR BUILD_STATIC)
		target_link_libraries (${testexename} ${GLIB_LIBRARIES})
	endif ()

	add_test (NAME ${testexename}
		  COMMAND "${CMAKE_BINARY_DIR}/bin/${testexename}" "${CMAKE_CURRENT_SOURCE_DIR}"
		  WORKING_DIRECTORY "${WORKING_DIRECTORY}")
	set_property (TEST ${testexename} PROPERTY ENVIRONMENT "LD_LIBRARY_PATH=${CMAKE_BINARY_DIR}/lib")

	add_subdirectory (example)
endif ()
